This is the Painterly Spell Icons pack (original link) created by John W. Bjerk, from jwbjerk.com and contributor of opengameart.org. According to the author, each spell comes in three power levels.  Additionally most spells have several (up to nine) color variations.

The colors were chosen for their distinctness, and to support a wide range of possible classes of magic and or damage types.  For instance the red version of the “enchant weapon” spell could be used to add fire damage to weapons.

All icons are 256×256, but have been designed to be easily recognizable down to 32×32. The pack contains the following icons:

• Enchant Weapon: 9 colors
• Protect: 9 colors
• Evil Eye: 2 colors
• Fireball: 4 colors
• Heal: 3 colors
• Beam of Light: 9 colors
• Haste: 3 colors
• Ice Shards: 3 colors
• Lightning: 9 colors
• Hurl Rock: 5 colors
• Entangling Vines: 4 colors
• Explosion: 5 colors
• Horror: 3 colors
• Leaf: 4 colors
• Runes: 4 colors
• Wild: 4 colors
• Wind: 4 colors
• Frames: 10 colors, 10 styles (not all styles have all colors)
• Air Burst: 4 colors
• Fire Arrows: 5 colors
• Fog: 7 colors
• Light: 7 colors
• Link: 4 colors
• Ice Needles: 5 colors
• Rip: 5 colors
• Shielding: 4 colors
• Slice: 4 colors
• Wind grasp: 5 colors

License

This  pack is licensed under the Creative Commons Attribution 3.0 Unported License.

Art attributions

If you use this pack, please include the following attribution in a visible location along with any other credits:

"Painterly Spell Icons" by J. W. Bjerk (eleazzaar) --
www.jwbjerk.com/art -- find this and other open art
at: http://opengameart.org

When possible link to page that presents the original art collection. For this asset pack, it would be ”Painterly Spell Icons” art by John W. Bjerk (opengameart.org).

About the artist

John W. Bjerk
I’m interested in a lot of things, primarily the intersection of technology & art. (I love & even dream in Photoshop!) I work as a Graphic Designer, sometimes wearing the geek or illustrator hat.

• Theme editor.
• Margin layout system.
• Brush skining system makes it easier to change any component’s style.
• Inproved class structure is more clear and easy to learn for newbies.
• Still small file size, little memory use.

Sample

/**
 * Copyright (c) 2012 - 2100 Sindney
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */
package
{
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.MouseEvent;

	import bloom.containers.*;
	import bloom.core.Margin;
	import bloom.themes.*;
	import bloom.*;

	/**
	 * HelloWorld
	 *
	 * @author sindney
	 */
	[SWF(backgroundColor = 0x000000, frameRate = 40, width = 200, height = 620)]
	public class HelloWorld extends Sprite {

		public function HelloWorld() {
			super();
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.showDefaultContextMenu = false;

			// setup theme first, we use colorTheme for example.
			ThemeBase.setTheme(new ColorTheme());

			// flow container object.
			var flowContainer:FlowContainer = new FlowContainer(this);
			flowContainer.direction = FlowContainer.VERTICALLY;
			flowContainer.move(10, 10);
			flowContainer.size(150, 600);

			var label:Label = new Label(flowContainer, "I'm a Label");
			// use component.margin to place object.
			label.margin.reset(5, 5, 0, 5);

			var button:Button = new Button(flowContainer, "I'm a Button", onButtonClick);

			var checkBox:CheckBox = new CheckBox(flowContainer, "I'm a CheckBox", true);
			checkBox.addEventListener(Event.CHANGE, onCheckBoxChanged);

			// with checkboxgroup, you can easily link a group of checkbox object(and he who extends checkbox).
			// set checkBoxGroup.index = -1 means there's no checkbox object currently.
			var checkBoxGroup:CheckBoxGroup = new CheckBoxGroup( -1);

			checkBox = new CheckBox(flowContainer, "CheckBox 0");
			checkBoxGroup.addChild(checkBox);

			checkBox = new CheckBox(flowContainer, "CheckBox 1");
			checkBoxGroup.addChild(checkBox);

			checkBox = new CheckBox(flowContainer, "CheckBox 2");
			checkBoxGroup.addChild(checkBox);

			// set target checkbox
			checkBoxGroup.index = 0;
			checkBoxGroup.addEventListener(Event.CHANGE, onCheckBoxGroupChanged);

			var numericStepper:NumericStepper = new NumericStepper(flowContainer, 50, 100, -100, 10);
			numericStepper.addEventListener(Event.CHANGE, onNumericStepperChanged);

			var slider:Slider = new Slider(flowContainer, Slider.HORIZONTALLY);
			slider = new Slider(flowContainer, Slider.VERTICALLY);

			var textInput:TextInput = new TextInput(flowContainer);
			var textBox:TextBox = new TextBox(flowContainer);

			var toggleButton:ToggleButton = new ToggleButton(flowContainer, "I'm a toggleButton");
			toggleButton.size(140, 20);

			var toggleSwitcher:ToggleSwitcher = new ToggleSwitcher(flowContainer, true);

			var progressBar:ProgressBar = new ProgressBar(flowContainer, 50);
		}

		private function onNumericStepperChanged(e:Event):void {
			trace("NumericStepper changed!");
		}

		private function onCheckBoxGroupChanged(e:Event):void {
			trace("CheckBoxGroup changed!");
		}

		private function onCheckBoxChanged(e:Event):void {
			trace("CheckBox changed!");
		}

		private function onButtonClick(e:MouseEvent):void {
			trace("Button clicked!");
		}

	}

}

• fps counter.
• current and max memory counters.
• frame ‘work’ time (in ms) counter.
• Graph of fps,frame time,memory counters.
• increase/decrease width of Stats graph with mouse wheel.
• Monitoring feature. (shows frame code execution time and frame render time.)
• Minimize stats to compact mode. (graph is still drawn in background.)
• can be dragged.
• buttons to change fps count and toggle monitoring feature, and minimize.
• Context menu

Sample

var stats:Stats = new Stats();
this.addChild(stats);
stats.width = 150;
stats.x = 10;
stats.y = 20;
//stats.isMinimized = true;
//stats.isDraggable = false;
stats.isMonitoring = true;
//stats.scale = 2;

The most important resource As3GameGears has is its data, a collection of tools with links, samples, licenses and more, all categorized. With that in mind, I thought it would be cool to make all that data accessible though an API.

I always wanted to create an API, but I never had anything worth sharing. Now that I have, I decided to make that side-project come true. First I got some design and structure inspiration from StackOverflow API, which I believe is a good API. After I used Restler (multi-protocol REST API Server written in PHP) for the REST stuff. Finally I wrote some code to synchronize the API and As3GameGears databases.

It was a nice goal to accomplish. I’ve learned a lot about APIs and WordPress database structure. The next step is the development of some widgets, so I can use the API.

You can check the As3GameGears API source code at Github.

Sample

package
{
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.KeyboardEvent;

	import nest.object.Container3D;
	import nest.view.Camera3D;
	import nest.view.ViewPort;

	public class DemoBase extends Sprite {

		protected var keys:Array = new Array();

		protected var view:ViewPort;
		protected var camera:Camera3D;
		protected var scene:Container3D;

		protected var controller:ObjectController;

		protected var speed:Number = 2;

		public function DemoBase() {
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			stage.frameRate = 60;

			camera = new Camera3D();
			scene = new Container3D();
			view = new ViewPort(800, 600, stage.stage3Ds[0], camera, scene);

			controller = new ObjectController(camera, stage);
			addChild(view.diagram);
			view.addEventListener(Event.CONTEXT3D_CREATE, onContext3DCreated);
		}

		private function onContext3DCreated(e:Event):void {
			stage.addEventListener(Event.RESIZE, onResize);
			stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);
			stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
			stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
		}

		private function onKeyDown(e:KeyboardEvent):void {
			keys[e.keyCode] = true;
		}

		private function onKeyUp(e:KeyboardEvent):void {
			keys[e.keyCode] = false;
		}

		private function onResize(e:Event):void {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}

		protected function onEnterFrame(e:Event):void {
			if (keys[87]) camera.moveForward(speed);
			if (keys[83]) camera.moveForward( -speed);
			if (keys[68]) camera.moveSideways(speed);
			if (keys[65]) camera.moveSideways( -speed);

			view.calculate();
			view.diagram.message = "Objects: " + view.numObjects + "\nTriangles: " + view.numTriangles + "\nVertices: " + view.numVertices;
		}

	}

}

• Easy-to-use API.
• Comprehensive structure.
• Behavior and behavior triggers.
• Particles can be custom MovieClip symbols.
• Multiple sources for a single emitter.
• Four kinds of basic-shaped sources.
• DisplayObjectSource for custom-shaped particle source.
• Bursting – sudden massive particle spawning.
• Gravitation simulation.
• Bubblemotion simulation.
• Deflector simulation.

• watch any property of any class
• customizable update rate
• customizable per-property color
• chat rendering for numeric values
• watch framerate, memory and Flash Player version
• ready to use framerate property

Sample

// get a singleton Monitor object
var monitor : Monitor = Monitor.monitor;

// set the update (refresh) rate to 15 updates per second
monitor.updateRate = 15.;

// add the monitor to the display list
stage.addChild(monitor);

// watch the rotationX property of the camera object with a scale value of 1 / (PI / 2)
monitor.watch(camera, "rotationX", 0x55ff00, 1. / (Math.PI / 2.), true);
// watch the rotationY property of the camera object with a scale value of 1 / (2 * PI)
monitor.watch(camera, "rotationY", 0xff5500, 1. / (2. * Math.PI), true);
// watch the rotationZ property of the camera object with no scale value (=> no chart rendering)
monitor.watch(camera, "rotationZ", 0x5599ff);

// watch multiple properties
monitor.watchProperties(physics,
                        ["processingTime", "speed"],
                        [0x00ff00, 0xff0000],
                        [1. / 40., 1. / 10.]);

// change the background color (0xAARRGGBB)
monitor.backgroundColor = 0x7f000000;

Sample

package {
	import away3d.containers.View3D;
	import away3d.debug.AwayStats;
	import away3d.entities.Mesh;
	import away3d.events.MouseEvent3D;
	import away3d.lights.PointLight;
	import away3d.materials.ColorMaterial;
	import away3d.primitives.Cone;
	import away3d.primitives.Cube;
	import away3d.primitives.Cylinder;
	import away3d.primitives.Plane;
	import away3d.primitives.Sphere;

	import awayphysics.collision.shapes.AWPBoxShape;
	import awayphysics.collision.shapes.AWPConeShape;
	import awayphysics.collision.shapes.AWPCylinderShape;
	import awayphysics.collision.shapes.AWPSphereShape;
	import awayphysics.collision.shapes.AWPStaticPlaneShape;
	import awayphysics.dynamics.AWPDynamicsWorld;
	import awayphysics.dynamics.AWPRigidBody;
	import awayphysics.debug.AWPDebugDraw;

	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Vector3D;

	[SWF(backgroundColor="#000000", frameRate="60", width="1024", height="768")]
	public class BasicTest extends Sprite {
		private var _view : View3D;
		private var _light : PointLight;
		private var _physicsWorld : AWPDynamicsWorld;
		private var _sphereShape : AWPSphereShape;
		private var _timeStep : Number = 1.0 / 60;

		private var debugDraw:AWPDebugDraw;

		public function BasicTest() {
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e : Event = null) : void {
			removeEventListener(Event.ADDED_TO_STAGE, init);

			_view = new View3D();
			this.addChild(_view);
			this.addChild(new AwayStats(_view));

			_light = new PointLight();
			_light.y = 2500;
			_light.z = -4000;
			_view.scene.addChild(_light);

			_view.camera.lens.far = 10000;
			_view.camera.y = _light.y;
			_view.camera.z = _light.z;
			_view.camera.rotationX = 25;

			// init the physics world
			_physicsWorld = AWPDynamicsWorld.getInstance();
			_physicsWorld.initWithDbvtBroadphase();

			debugDraw = new AWPDebugDraw(_view, _physicsWorld);
			debugDraw.debugMode |= AWPDebugDraw.DBG_DrawTransform;

			// create ground mesh
			var material : ColorMaterial = new ColorMaterial(0x252525);
			material.lights = [_light];
			var ground : Plane = new Plane(material, 50000, 50000);
			ground.mouseEnabled = true;
			ground.mouseDetails = true;
			ground.addEventListener(MouseEvent3D.MOUSE_UP, onMouseUp);
			_view.scene.addChild(ground);

			// create ground shape and rigidbody
			var groundShape : AWPStaticPlaneShape = new AWPStaticPlaneShape(new Vector3D(0, 1, 0));
			var groundRigidbody : AWPRigidBody = new AWPRigidBody(groundShape, ground, 0);
			_physicsWorld.addRigidBody(groundRigidbody);

			// create a wall
			var wall : Cube = new Cube(material, 20000, 2000, 100);
			_view.scene.addChild(wall);

			var wallShape : AWPBoxShape = new AWPBoxShape(20000, 2000, 100);
			var wallRigidbody : AWPRigidBody = new AWPRigidBody(wallShape, wall, 0);
			_physicsWorld.addRigidBody(wallRigidbody);			

			wallRigidbody.position = new Vector3D(0, 1000, 2000);

			//material = new ColorMaterial(0xfc6a11);
			//material.lightPicker = new LightPickerBase();

			// create rigidbody shapes
			_sphereShape = new AWPSphereShape(100);
			var boxShape : AWPBoxShape = new AWPBoxShape(200, 200, 200);
			var cylinderShape : AWPCylinderShape = new AWPCylinderShape(100, 200);
			var coneShape : AWPConeShape = new AWPConeShape(100, 200);

			// create rigidbodies
			var mesh : Mesh;
			var body : AWPRigidBody;
			var numx : int = 2;
			var numy : int = 8;
			var numz : int = 1;
			for (var i : int = 0; i < numx; i++ ) {
				for (var j : int = 0; j < numz; j++ ) {
					for (var k : int = 0; k < numy; k++ ) {
						// create boxes
						mesh = new Cube(material, 200, 200, 200);
						//_view.scene.addChild(mesh);
						body = new AWPRigidBody(boxShape, mesh, 1);
						body.friction = .9;
						body.ccdSweptSphereRadius = 0.5;
						body.ccdMotionThreshold = 1;
						body.position = new Vector3D(-1000 + i * 200, 100 + k * 200, j * 200);
						_physicsWorld.addRigidBody(body);

						// create cylinders
						mesh = new Cylinder(material, 100, 100, 200);
						//_view.scene.addChild(mesh);
						body = new AWPRigidBody(cylinderShape, mesh, 1);
						body.friction = .9;
						body.ccdSweptSphereRadius = 0.5;
						body.ccdMotionThreshold = 1;
						body.position = new Vector3D(1000 + i * 200, 100 + k * 200, j * 200);
						_physicsWorld.addRigidBody(body);

						// create the Cones
						mesh = new Cone(material, 100, 200);
						//_view.scene.addChild(mesh);
						body = new AWPRigidBody(coneShape, mesh, 1);
						body.friction = .9;
						body.ccdSweptSphereRadius = 0.5;
						body.ccdMotionThreshold = 1;
						body.position = new Vector3D(i * 200, 100 + k * 230, j * 200);
						_physicsWorld.addRigidBody(body);
					}
				}
			}

			stage.addEventListener(Event.ENTER_FRAME, handleEnterFrame);
		}

		private function onMouseUp(event : MouseEvent3D) : void {
			var pos : Vector3D = _view.camera.position;
			var mpos : Vector3D = new Vector3D(event.localX, event.localY, event.localZ);

			var impulse : Vector3D = mpos.subtract(pos);
			impulse.normalize();
			impulse.scaleBy(2000);

			// shoot a sphere
			var material : ColorMaterial = new ColorMaterial(0xb35b11);
			material.lights = [_light];

			var sphere : Sphere = new Sphere(material, 100);
			//_view.scene.addChild(sphere);

			var body : AWPRigidBody = new AWPRigidBody(_sphereShape, sphere, 2);
			body.position = pos;
			body.ccdSweptSphereRadius = 0.5;
			body.ccdMotionThreshold = 1;
			_physicsWorld.addRigidBody(body);

			body.applyCentralImpulse(impulse);
		}

		private function handleEnterFrame(e : Event) : void {
			_physicsWorld.step(_timeStep, 1, _timeStep);

			debugDraw.debugDrawWorld();
			_view.render();
		}
	}
}

The project is in early development, but it’s very promising. If you are interested, watch the project on Github and take a look at some demos.